學習目标

1、 知道單片機的特點及其結構。

2、 識讀MCS—51各引腳并掌握其工作原理。。

3、 懂并按要求編寫基本的單片機指令。

4、電子密碼鎖元件的特點。

5、懂電子密碼鎖原理圖。

6、懂電子密碼鎖安裝圖。

7、懂電子密碼鎖的程序。

8、行安裝、調試、維修電子密碼鎖。

學習内容：

1、 單片機的特點及其結構。

2、 識讀MCS—51各引腳并掌握其工作原理。

3、 識讀指令的結構，類型及編寫

4、 電子鎖電子元件的特點。

5、電子鎖的工作原理、特點、種類。

6、電子鎖電子元件的測試。

7、進行電子鎖程序的設計。

本學習情境學時:44學時

本課題的教學步驟可分為：

1、下發任務書

2、學習流程

3、引導問題

4、有關表格

5、自我測試題（評價标準、測試題）

任務書

随着生活水平的提高，人們對自己所處環境安全性要求越來越高。本設計主要是基于單片機智能鎖的硬件和軟件的設計及實現方法，這種電路設計具有按鍵有效提示,輸入錯誤提示,控制開鎖電平,控制報警電路,修改密碼等多種功能"可在意外洩密的情況下随時修改密碼"4位數密碼共一萬組不重複組合,保密性強,靈活性高,特别适用于家庭，辦公室，學生宿舍及賓館等公開場所。

通過本課題的學習，你能夠獨立完成密碼鎖的組裝，并且可以進行它類型密碼鎖的維修；下圖為密碼鎖電原理圖。

圖1 電子密碼鎖原理圖

圖2 實物圖

總體方案設計

設計思路

共設了9個用戶輸入鍵，其中隻有4個是有效的密碼按鍵，其它的都是幹擾按鍵，若按下幹擾鍵，鍵盤輸入電路自動清零，原先輸入的密碼無效，需要重新輸入；如果用戶輸入密碼的時間超過40秒（一般情況下，用戶不會超過40秒，若用戶覺得不便，還可以修改）電路将報警80秒，若電路連續報警三次，電路将鎖定鍵盤5分鐘，防止他人的非法操作。

采用AT89S51為核心的單片機控制方案。利用單片機靈活的編程設計和豐富的IO端口，及其控制的準确性，不但能實現基本的密碼鎖功能，還能添加調電存儲、聲光提示甚至添加遙控控制功能。其原理如圖2－2所示。

圖2－2單片機控制方案

開鎖機構

通過單片機送給開鎖執行機構，電路驅動電磁鎖吸合，從而達到開鎖的目的。其原理如圖2－3所示。

圖2－3密碼鎖開鎖機構示意圖

當用戶輸入的密碼正确時，單片機便輸出開門信号，送到開鎖驅動電路，然後驅動電磁鎖，達到開門的目的。其實際電路如圖2－4所示。

電路由驅動和開鎖兩級組成。由D5、R1、T10組成驅動電路，其中T10可以選擇普通的小功率三極管如9014、9018都可以滿足要求。D5是開鎖指示燈；由D6、C24、T11組成開鎖。其中D6、C24是為了消除電磁鎖可能産生的反向高電壓以及可能産生的電磁幹擾。T11可選用中功率的三極管如8050，電磁鎖的選用要視情況而定，但是吸合力要足夠且有一定的餘量。

注：在設計中，暫時用發光二極管代替電磁鎖，發光管亮，表示開鎖；滅，表示沒有開鎖。

圖2－4密碼鎖開鎖機構電路圖

按鍵電路設計

由于設計要求使用矩陣鍵盤，所以本設計就采用行列式鍵盤，同時也能減少鍵盤與單片機接口時所占用的I/O線的數目，在按鍵比較多的時候，通常采用這樣方法。其原理如圖2－5所示。

圖2－5 行列式鍵盤原理電路圖

每一條水平（行線）與垂直線（列線）的交叉處不相通，而是通過一個按鍵來連通，利用這種行列式矩陣結構隻需要N條行線和M條列線，即可組成具有N×M個按鍵的鍵盤。

首先辨别鍵盤中有無鍵按下，有單片機I/O口向鍵盤送全掃描字，然後讀入行線狀态來判斷。方法是：向行線輸出全掃描字00H，把全部列線置為低電平，然後将列線的電平狀态讀入累加器A中。如果有按鍵按下，總會有一根行線電平被拉至低電平從而使行線不全為1。判斷鍵盤中哪一個鍵被按下使通過将列線逐列置低電平後，檢查行輸入狀态來實現的。方法是：依次給列線送低電平，然後查所有行線狀态，如果全為1，則所按下的鍵不在此列；如果不全為1，則所按下的鍵必在此列，而且是在與零電平行線相交的交點上的那個鍵。

按鍵的操作面闆如圖2－6所示。共計數字鍵10個，功能鍵2個。

圖2－6按鍵操作面闆示意圖

10個數字鍵用來輸入密碼，另外2個功能鍵分别是：開鎖和上鎖。上鎖和開鎖的過程在1-2中已經詳細介紹,在此不再說。。

面闆上還有一個蜂鳴器，其中一個功能是用來指示操作的按鍵是否在成功的按下；另外一個功能是當用戶輸入密碼錯誤的次數超過了3次，鳴笛以示報警。

顯示電路設計

本系統設計的顯示電路為了節約單片機的接口資源而采用串行顯示的方式，隻使用單片機的兩個串行口，就可以完成單片機的顯示功能，顯示電路的電路原理圖如圖2－7所示。

電路設定：當程序檢測在5分鐘内沒有按鍵操作的時候，就關閉顯示。這個功能使用程序來實現的，一旦沒有按鍵動作就啟動一個定時器，檢測在5分鐘内沒有按鍵動作的時候，啟動一個程序，關閉顯示，這樣可以達到節省電能的目的。

從單片機串口輸出的信号先送到左邊的移位寄存器（74HC164）,由于移位脈沖的作用，使數據向右移，達到顯示的目的。移位寄存器74HC164還兼作數碼管的驅動，插頭1（header1）接電源，插頭2（header2）接數據和脈沖輸出端。電路中的三個整流管D1~D3的作用是降低數碼管的工作電壓，增加其使用壽命。

圖2－7顯示器原理圖

程序

程序：

;=====================定義參數=============================

LED_ON BIT 00H;數碼管亮暗标志（1為亮，0為暗）

KEYCARD BIT 01H;按鍵标志

PWD_RIGHT BIT 02H;密碼是否正确（1 為正确，0為錯誤）

KEY_LOCK BIT 03H;鍵盤鎖定（1為鎖，0為開）

SOND BIT P1.4;蜂鳴器

GREEN BIT P1.5;綠燈

RED BIT P1.6;紅燈

LED1 EQU 50H;數碼管自動變暗時間數1

KEYS EQU 53H;按鍵鍵值

KEY1 EQU 54H;按鍵行值

PWD1 EQU 56H;存密碼1

PWD2 EQU 57H;存密碼2

PWD3 EQU 58H;存密碼3

PWD4 EQU 59H;存密碼4

SHOW1 EQU 5AH;顯示1

SHOW2 EQU 5BH;顯示2

SHOW3 EQU 5CH;顯示3

SHOW4 EQU 5DH;顯示4

SHOW0 EQU 5EH;臨時用

;====================程序開始==============================

ORG 0000H

AJMP INIT

;=====================初始化===============================

ORG 0030H

INIT:

MOV P0, #40H

MOV P2, #0FH

MOV P3, #00H

MOV LED1, #3FH

MOV KEYS, #00H

MOV KEY1, #00H

MOV SHOW0,#00H

MOV SHOW1,#00H

MOV SHOW2,#10H

MOV SHOW3,#20H

MOV SHOW4,#30H

LCALL PWD_INIT

SETB LED_ON

CLR PWD_RIGHT

SETB SOND

SETB RED

SETB GREEN

CLR KEY_LOCK

CLR KEYCARD

AJMP MAIN

;===========================================================主程序======================================================

MAIN:

MOV P2,#0FH

MOV P3,#00H

LCALL KEY_FIRST ;調用鍵盤程序

JNB KEYCARD,MAIN ;KEYCARD=0時，無鍵按下跳回MAIN

LCALL KEY_MAIN ;KEYCARD=0時，調用鍵盤處理程序

JNB KEYCARD,MAIN

LJMP MKEY_FUNCTION ;跳到主程序鍵盤各按鍵處理程序

;============================================================END========================================================

;=====================檢測按鍵第一次按下========================

KEY_FIRST:

JNB LED_ON,KEY_LOOP

MOV A, P2 ;數碼管亮時掃描

ANL A, #0FH ;屏敝掉高4位

CJNE A, #0FH,KEY_SECOND ;判斷是否有鍵按下

CLR KEYCARD ;無鍵則KEYCARD置0

LCALL LED_DISPLAY ;調用顯示子程序

DJNZ LED1, ESC

CLR LED_ON

MOV LED1, #03FH

ESC:

RET

KEY_LOOP: ;數碼管暗時掃描

MOV A, P2

ANL A, #0FH

CJNE A, #0FH,KEY_SECOND

CLR KEYCARD

RET

;=======================檢測按鍵第二次按下=================

KEY_SECOND:

LCALL BEEP1 ;按鍵響聲

JNB LED_ON,KEY_EXIT1 ;如果LED是暗的，則置LED_ON為1

MOV LED1, #03FH

LCALL DELAY10MS ;去抖，延時10ms

MOV A, P2 ;重新掃描鍵盤

ANL A, #0FH

CJNE A, #0FH,KEY_EN ;有鍵按下，則置KEYCARD為1

CLR KEYCARD ;無鍵按下，則置KEYCARD為0

RET

KEY_EXIT1:

LCALL KEY_RELEASE

SETB LED_ON

RET

KEY_EN:

SETB KEYCARD ;置KEYCARD為1

RET

;===============================================KEY_MAIN=================================================

KEY_MAIN:

MOV R3,#0EH

MOV R4,#04H ;循環次數

KEY_ROW:

MOV P3,R3

MOV A,P2

ANL A,#0FH

MOV KEY1,R3 ;将行信息存到KEY1中

CJNE A,#0FH,KEY_WORD ;是該行則跳到鍵值計算程序

MOV A,R3

SETB C

RLC A ;帶進位循環左移

ANL A,#0FH

MOV R3,A

DJNZ R4, KEY_ROW

CLR KEYCARD

RET

;================鍵值計算========================

KEY_WORD:

SWAP A

ORL A,KEY1 ;列＋行＝鍵值

MOV KEYS,A ;鍵值存到KEYS中

RET

;==================================主程序各按鍵功能=======================================

MKEY_FUNCTION:

MOV KEYS,A ;鍵值賦給A

MK0:

CJNE A,#0EEH,MK1

CLR KEYCARD

MOV SHOW1,#0BH

MOV SHOW2,#1BH

MOV SHOW3,#2BH

MOV SHOW4,#3BH

LCALL KEY_RELEASE ;按鍵松開程序

MOV R5,#05H

MOV R6,#03H

CLR KEY_LOCK

LOGIN_MAIN: ;輸入密碼主程序

MOV P2, #0FH

MOV P3, #00H

LCALL KEY_FIRST ;調用鍵盤掃描程序

JNB KEYCARD,LOGIN_MAIN

LCALL KEY_MAIN ;調用鍵盤處理程序

LJMP LKEY_FUNCTION ;跳到輸密碼時各鍵功能處理程序

MK1:

LCALL KEY_RELEASE

LJMP MAIN

;========＝＝＝＝＝＝＝＝=========================END====================================

;==========================出廠密碼============================

PWD_INIT:

MOV PWD1, #01H

MOV PWD2, #02H

MOV PWD3, #03H

MOV PWD4, #04H

RET

;======================================輸入密碼時各按鍵功能====================================

LKEY_FUNCTION:

MOV A,KEYS

;=================無效鍵============================

LK0:

CJNE A,#0EEH,LK1

LCALL LAMP_RED ;閃紅燈

LCALL KEY_RELEASE

LJMP LOGIN_MAIN ;返回輸入密碼主程序

LK1:

CJNE A,#0EDH,LK2

LCALL LAMP_RED

LCALL KEY_RELEASE

LJMP LOGIN_MAIN

LK2:

CJNE A,#0EBH,LK3

LCALL LAMP_RED

LCALL KEY_RELEASE

LJMP LOGIN_MAIN

;=================退出鍵==================

LK3:

CJNE A,#0E7H,LK4

MOV SHOW1,#00H

MOV SHOW2,#10H

MOV SHOW3,#20H

MOV SHOW4,#30H

CLR KEY_LOCK

LJMP MAIN ;返回主程序

;===============清除鍵=========================

LK4:

CJNE A,#07BH,LK5

MOV SHOW1,#0BH

MOV SHOW2,#1BH

MOV SHOW3,#2BH

MOV SHOW4,#3BH

MOV R5, #05H

LCALL KEY_RELEASE

LJMP LOGIN_MAIN

;================确定鍵=========================

LK5:

CJNE A,#077H,LK6

LCALL PWD_COMPARE ;調用密碼檢測子程序

LCALL KEY_RELEASE

JB PWD_RIGHT,SYS_LOGIN ;PWD_RIGHT為1時表示密碼正确，跳到SYS_LOGIN

DJNZ R6,LK5_EXIT ;否則将輸入次數R6減1

INC R6 ;若輸入次數已經是3次了，就保持R6為1

SETB KEY_LOCK ;置KEY_LOCK為1

LK5_EXIT:

MOV SHOW1,#0BH

MOV SHOW2,#1BH

MOV SHOW3,#2BH

MOV SHOW4,#3BH

MOV R5, #05H

LK5_ESC:

LCALL KEY_RELEASE

LJMP LOGIN_MAIN ;返回輸入密碼主程序

;=============0-9數字鍵========================

LK6:

MOV R0,#00H

JB KEY_LOCK,LK6_EXIT ;置KEY_LOCK為1時鎖定數字鍵

DJNZ R5,LKEY_NUM ;輸入個數滿4個則鎖定數字鍵，否則R5減1

INC R5 ;若輸入個數已經是4個了，就保持R5為1

LK6_EXIT:

LCALL BEEP2 ;誤操作鍵盤發聲

AJMP LK6_ESC

LKEY_NUM:

MOV A,R0

INC R0

MOV DPTR,#KEY_VALUE

MOVC A,@A DPTR

CJNE A,KEYS,LKEY_NUM

DEC R0

MOV A,R0

MOV DPTR,#TAB

MOVC A,@A DPTR

MOV KEYS,A

ORL A,#30H

MOV SHOW0,A

LCALL LED_MOVE ;調用左移功能

MOV SHOW4,SHOW0

LK6_ESC:

ACALL KEY_RELEASE

LJMP LOGIN_MAIN

;=======================================END=================================================

;================================登陸系統========================================

SYS_LOGIN:

MOV SHOW1,#01H

MOV SHOW2,#11H

MOV SHOW3,#21H

MOV SHOW4,#31H

CLR GREEN ;綠燈亮表示開鎖成功

SYS_MAIN: ;開鎖狀态主程序

MOV P2, #0FH

MOV P3, #00H

LCALL KEY_FIRST ;調用鍵盤掃描程序

JNB KEYCARD,SYS_MAIN

LCALL KEY_MAIN ;調用鍵盤處理程序

LJMP SYSKEY_FUNCTION

;==================================登陸系統後各鍵功能===================================

SYSKEY_FUNCTION:

MOV A,KEYS

;================修改密碼鍵===============

SYSK1:

CJNE A,#0EDH,SYSK2

SET_PWD:

MOV R5,#05H

CLR KEY_LOCK

MOV SHOW1,#0AH

MOV SHOW2,#1AH

MOV SHOW3,#2AH

MOV SHOW4,#3AH

SETPWD_MAIN: ;修改密碼主程序

MOV P2, #0FH

MOV P3, #00H

LCALL KEY_FIRST ;調用鍵盤掃描程序

JNB KEYCARD,SETPWD_MAIN

LCALL KEY_MAIN ;調用鍵盤處理程序

LJMP SKEY_FUNCTION

;================恢複出廠設置===========

SYSK2:

CJNE A,#0EBH,SYSK3

LCALL PWD_INIT

LCALL KEY_RELEASE

LJMP SYS_MAIN

;=================退出鍵==================

SYSK3:

CJNE A,#0E7H,SYSK4

MOV SHOW1,#00H

MOV SHOW2,#10H

MOV SHOW3,#20H

MOV SHOW4,#30H

CLR KEY_LOCK

SETB GREEN ;關綠燈

LJMP MAIN ;跳回主程序

;==================無效鍵==================

SYSK4:

LCALL BEEP2

LCALL KEY_RELEASE

LJMP SYS_MAIN

;==================================END==================================================

;=================================修改密碼各鍵功能==========================================

SKEY_FUNCTION:

MOV A,KEYS

;=================無效鍵=====================

SK0:

CJNE A,#0EEH,SK1

LCALL LAMP_RED

LCALL KEY_RELEASE

LJMP SETPWD_MAIN

SK1:

CJNE A,#0EDH,SK2

LCALL LAMP_RED

LCALL KEY_RELEASE

LJMP SETPWD_MAIN

SK2:

CJNE A,#0EBH,SK3

LCALL LAMP_RED

LCALL KEY_RELEASE

LJMP SETPWD_MAIN

;=================退出修改密碼================

SK3:

CJNE A,#0E7H,SK4

MOV SHOW1,#01H

MOV SHOW2,#11H

MOV SHOW3,#21H

MOV SHOW4,#31H

LCALL KEY_RELEASE

LJMP SYS_MAIN

;==================清除鍵=====================

SK4:

CJNE A,#07BH,SK5

MOV SHOW1,#0AH

MOV SHOW2,#1AH

MOV SHOW3,#2AH

MOV SHOW4,#3AH

MOV R5,#05H

LCALL KEY_RELEASE

LJMP SETPWD_MAIN

;=================确認鍵======================

SK5:

CJNE A,#077H,SK6

LCALL KEY_RELEASE

CJNE R5,#01H,SETPWD_FAIL ;當輸入個數小于4個，則密碼修改不成功

LCALL SETPWD_SUCCESS ;成功調用SETPWD_SUCCESS

LJMP SYS_MAIN

;================0-9數字鍵=================

SK6:

MOV R0,#00H

DJNZ R5,SKEY_NUM

INC R5

LCALL BEEP2

AJMP SK6_ESC

SKEY_NUM:

MOV A,R0

INC R0

MOV DPTR,#KEY_VALUE

MOVC A,@A DPTR

CJNE A,KEYS,SKEY_NUM

DEC R0

MOV A,R0

MOV DPTR,#TAB

MOVC A,@A DPTR

MOV KEYS,A

ORL A,#30H

MOV SHOW0,A

LCALL LED_MOVE

MOV SHOW4,SHOW0

SK6_ESC:

ACALL KEY_RELEASE

LJMP SETPWD_MAIN

;===========================================END=============================================

;====================================修改密碼失敗====================================

SETPWD_FAIL:

LJMP SET_PWD

;====================================修改密碼成功==================================

SETPWD_SUCCESS:

ANL SHOW1,#0FH

ANL SHOW2,#0FH

ANL SHOW3,#0FH

ANL SHOW4,#0FH

MOV PWD1,SHOW1

MOV PWD2,SHOW2

MOV PWD3,SHOW3

MOV PWD4,SHOW4

MOV SHOW1,#01H

MOV SHOW2,#11H

MOV SHOW3,#21H

MOV SHOW4,#31H

LCALL LAMP_GREEN ;閃綠燈

RET

;=====================================左移功能==============================================

LED_MOVE:

CLR C

MOV A, SHOW2

SUBB A,#10H

MOV SHOW1,A

CLR C

MOV A, SHOW3

SUBB A,#10H

MOV SHOW2,A

CLR C

MOV A, SHOW4

SUBB A,#10H

MOV SHOW3,A

RET

;======================================密碼檢測========================================

PWD_COMPARE:

MOV A, SHOW1

ANL A, #0FH

CJNE A, PWD1,PWD_EXIT

MOV A, SHOW2

ANL A, #0FH

CJNE A, PWD2,PWD_EXIT

MOV A, SHOW3

ANL A, #0FH

CJNE A, PWD3,PWD_EXIT

MOV A, SHOW4

ANL A, #0FH

CJNE A, PWD4,PWD_EXIT

SETB PWD_RIGHT

AJMP PWD_ESC

PWD_EXIT:

CLR PWD_RIGHT

PWD_ESC:

RET

;======================================判斷鍵是否釋放====================================

KEY_RELEASE:

MOV P3,#00H

KEY_LOSEN:

MOV A,P2

ANL A,#0FH

LCALL LED_DISPLAY

CJNE A,#0FH,KEY_LOSEN

RET

;=======================================LED顯示================================

LED_DISPLAY:

JNB LED_ON,LED_OFF

MOV P0, SHOW1

LCALL DELAY10MS

MOV P0, SHOW2

LCALL DELAY10MS

MOV P0, SHOW3

LCALL DELAY10MS

MOV P0, SHOW4

LCALL DELAY10MS

LED_OFF:

MOV P0, #4FH

RET

;========================正常按鍵響聲===========================

BEEP1:

CLR SOND

LCALL DELAY1

SETB SOND

RET

;========================非法按鍵響聲============================

BEEP2:

CLR SOND

LCALL DELAY100MS

LCALL DELAY100MS

SETB SOND

RET

;=========================操作有誤閃紅燈=================================

LAMP_RED:

MOV R2,#06H

MOV R1,#0FFH

LAMP_LOOP:

DJNZ R1,LAMP_LOOP

CPL RED

MOV R1,#0FFH

DJNZ R2,LAMP_LOOP

SETB RED

RET

;==========================修改密碼成功閃綠燈==========================================

LAMP_GREEN:

MOV R2,#06H

MOV R1,#0FFH

LAMP_LOOP1:

DJNZ R1,LAMP_LOOP1

CPL GREEN

MOV R1,#0FFH

DJNZ R2,LAMP_LOOP1

CLR GREEN

RET

;========================10MS延時===========================

DELAY10MS:

MOV R2,#04H

LOOP3:

MOV R1,#0F9H

LOOP4:

DJNZ R1,LOOP4

DJNZ R2,LOOP3

RET

;========================100MS延時===========================

DELAY100MS:

MOV R2,#0FFH

LOOP7:

MOV R1,#0FFH

LOOP8:

DJNZ R1,LOOP8

DJNZ R2,LOOP7

RET

;=========================聲音延時===========================

DELAY1:

MOV R2,#0FFH

LOOP5:

MOV R1,#03FH

LOOP6:

DJNZ R1,LOOP6

DJNZ R2,LOOP5

RET

;==========================鍵值表===========================

KEY_VALUE: DB 0EEH,0EDH,0EBH,0E7H,0DEH,0DDH,0DBH,0D7H,0BEH,0BDH,0BBH,0B7H,07EH,07DH,07BH,077H

;==========================數字表===========================

TAB: DB 00H,00H,00H,00H,00H,01H,02H,03H,04H,05H,06H,07H,08H,09H

預備知識：

1、 彙編語言語句一般格式為_____________。

2、 什麼是尋址方式？尋址方式分為：____________、_____________、______________、

3、 傳送指令的分類及其格式

4、 程序的基本結構有___________、_____________、_____________三種。

5、 按控制條件，循環程序可分為_____________和_____________兩種形式。

6、 51系列的單片機的RAM為_____________,

7、 51系列的中斷源為_____________個，_____________個優先級。

8、 總線分為_____________、_____________、_____________三類。

9、 什麼是時鐘周期、機器周期、指令周期？三者之間有何聯系？

10、 在邏輯電路中，輸入和輸出隻有兩種狀态，即_____________和_____________。通常以邏輯_____________和邏輯_____________表示電平高低

11、 常用邏輯電路有_____________、_____________、_____________、_____________、_____________、_____________。_____________。

12、 MCS-51的CPU能處理_____________位二進制數或代碼。

13、 51系列共有_____________個_____________位的定時器/計數器。

14、 I/O是什麼？I/O口是什麼？

15、 MCS-51單片機在物理結構上有_____________個存儲空間。分别是_____________、_____________、_____________、_____________。

16、 程序内存ROM尋址範圍從_____________到_____________，容量為_____________KB。

17、 74138譯碼器有_____________個輸入端：分别是_____________，

_____________個輸出端，分别是_____________。

18、 80C51單片機共有_____________條指令，這些條指令共有_____________種尋址方式。

19、 操作碼與操作數之間必須用_____________分開，操作數與操作數之間必須用逗号_____________分開。

20、 設某單片機系統的外接晶振頻率為6MHz，使用定時器1以方式0産生周期為500ms的等寬正方波連續脈沖，并由P1.0輸出。試寫出其設計程序。

21、 說明下列指令中源操作數采用的尋址方式。

　MOV R5，R7

　MOV A，55H

　MOV A，＃55H

JMP @A DPTR

22、 段數碼管從内部接線上分_____________和_____________兩種

23、 機器語言指令由_______和_______兩部分組成.

24、 八段碼顯示器的結構及其工作原理。

25、 如何用八段碼顯示器顯示數字“3”？

流程卡：（2個課時）

電路闆制作：（15個課時）

1、 準備本項任務所需的材料、工具，

2、 如果不全，缺哪些？

3、 根據上一項目的制作步驟進行操作。

材料明細卡

平分卡：（2個課時）

數字鐘的組裝與維修（滿分100分）

評分頁

工作小結：（1個課時）

更多精彩资讯请关注tft每日頭條，我们将持续为您更新最新资讯!